軌道
/
Elixir
Elixir
/
課程大綱
/
關鍵字陣列
關鍵

關鍵字陣列 在 Elixir

3 個練習

關於 關鍵字陣列

關鍵字清單是由 {key, value} 元組組成的陣列。關鍵字清單有兩種寫法:

# concise
[month: "April", year: 2018]

# explicit
[{:month, "April"}, {:year, 2018}]

鍵必須是原子

並不是每個由 2 元組構成的陣列都是關鍵字清單。鍵必須是原子:

Keyword.keyword?([{"month", "April"}])
# => false

如果你想在鍵裡使用字母、數字和 _ 以外的字元,就需要用引號把它包起來。不過,這麼做並不會讓它變成字串,它仍然是一個原子。

Keyword.keyword?(["day of week": "Monday"])
# => true

鍵可以重複

關鍵字清單中的鍵可以重複,而且鍵值對是有順序的。當你試著取得某個鍵底下的單一值時,你會拿到第一個值,同一個鍵底下的其他值則會被默默忽略。

list = [month: "April", month: "May"]

Keyword.get_values(list, :month)
# => ["April", "May"]

Keyword.get(list, :month)
# => "April"

關鍵字清單也支援Access behaviour。

list[:month]
# => "April"

關鍵字清單作為選項

關鍵字清單的特性,讓它成為 Elixir 中傳遞選項給函式的預設機制。

在學習if時,你看過一種特別的簡短語法:

if age >= 16, do: "beer", else: "no beer"

這看起來像是if接受兩個引數,但do:和else:這一對其實是單一個引數,也就是一個關鍵字清單。同樣的程式碼也可以寫成:

if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]

把關鍵字清單當作函式選項的用法實在太常見,因此 Elixir 允許你在關鍵字清單是傳給函式的最後一個引數時,省略方括號。

由於在 Elixir 語法中,元組、陣列、映射等都被視為與函式呼叫相同,所以這個特性對它們也適用。

[1, 2, three: 3]
# => [1, 2, {:three, 3}]

模式匹配

如果想用簡潔語法成功對關鍵字清單做模式匹配,你必須依照正確的順序列出所有的鍵。這使得模式匹配不太可能成為處理關鍵字清單的選擇。請改用Keyword模組或Access behaviour。

[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

關鍵字清單與映射

關鍵字清單 映射
鍵的型別 原子 任意型別,同一個映射中可以混用
重複的鍵 可以 不行
鍵有順序 有 沒有
存取 list[:key], Keyword.get/2 map.key, map[:key], Map.get/2
存取時間 線性 對數
模式匹配 不太實用 實用

更快的存取時間、更有彈性的鍵型別,以及實用的模式匹配,讓映射在大多數情況下成為預設選擇。

當你的資料量不大,但需要重複的鍵或特定順序的鍵時,就使用關鍵字清單。

透過 GitHub 編輯 連結會在新視窗或分頁中開啟

學習 關鍵字陣列

練習已鎖定

再解鎖 1 個練習,就能練習 關鍵字陣列