Parcours
/
Elixir
Elixir
/
Programme
/
Listes de mots-clés
Li

Listes de mots-clés en Elixir

3 exercices

À propos de Listes de mots-clés

Une liste de mots-clés est une liste de tuples {key, value}. Il y a deux façons d'écrire une liste de mots-clés :

# concise
[month: "April", year: 2018]

# explicit
[{:month, "April"}, {:year, 2018}]

Les clés doivent être des atomes

Une liste de tuples de deux éléments n'est pas forcément une liste de mots-clés. Les clés doivent être des atomes :

Keyword.keyword?([{"month", "April"}])
# => false

Si tu veux utiliser d'autres caractères que des lettres, des chiffres et _ dans la clé, tu dois l'entourer de guillemets. Cela n'en fait pas pour autant une string : ça reste un atome.

Keyword.keyword?(["day of week": "Monday"])
# => true

Les clés peuvent se répéter

Les clés d'une liste de mots-clés peuvent se répéter, et les paires clé-valeur sont ordonnées. Quand on essaie d'obtenir une seule valeur associée à une clé donnée, on obtient la première valeur, et les autres valeurs associées à la même clé sont silencieusement ignorées.

list = [month: "April", month: "May"]

Keyword.get_values(list, :month)
# => ["April", "May"]

Keyword.get(list, :month)
# => "April"

Les listes de mots-clés prennent aussi en charge le comportement Access.

list[:month]
# => "April"

Les listes de mots-clés comme options

Les caractéristiques des listes de mots-clés en ont fait le mécanisme par défaut pour passer des options aux fonctions en Elixir.

Quand tu as découvert if, tu as vu une syntaxe raccourcie particulière :

if age >= 16, do: "beer", else: "no beer"

On pourrait croire que if accepte deux arguments, mais la paire do: et else: est en réalité un seul argument : une liste de mots-clés. Le même code pourrait s'écrire ainsi :

if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]

L'usage des listes de mots-clés comme options de fonction est si courant qu'Elixir te permet d'omettre les crochets quand la liste de mots-clés est le dernier argument passé à une fonction.

Comme les tuples, les listes, les maps et d'autres structures sont traités de la même façon que les appels de fonction dans la syntaxe Elixir, cette propriété s'applique aussi à eux.

[1, 2, three: 3]
# => [1, 2, {:three, 3}]

Filtrage par motif

Pour filtrer une liste de mots-clés par motif avec la syntaxe concise, il faudrait préciser toutes les clés dans le bon ordre. Le filtrage par motif est donc rarement le bon choix pour manipuler des listes de mots-clés. Utilise plutôt le module Keyword ou le comportement Access.

[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

Listes de mots-clés ou maps

Liste de mots-clés Map
Type de clé Atomes N'importe lequel, mélange possible dans une même map
Clés en double Oui Non
Clés ordonnées Oui Non
Accès list[:key], Keyword.get/2 map.key, map[:key], Map.get/2
Temps d'accès Linéaire Logarithmique
Filtrage par motif Pas très utile Utile

Un temps d'accès plus rapide, un type de clé flexible et un filtrage par motif utile font des maps le choix par défaut dans la plupart des cas.

Utilise les listes de mots-clés quand tu n'as pas beaucoup de données, mais que tu as besoin de clés en double ou de clés dans un ordre précis.

Modifie via GitHub Le lien s'ouvre dans une nouvelle fenêtre ou un nouvel onglet

Apprends Listes de mots-clés

L'entraînement est verrouillé

Déverrouille 1 exercice de plus pour t'entraîner sur Listes de mots-clés