トラック
/
Elixir
Elixir
/
シラバス
/
キーワードリスト
キー

キーワードリスト の Elixir

3個の演習

キーワードリストについて

キーワードリストとは、{key, value}というタプルのリストです。キーワードリストの書き方には2通りあります。

# concise
[month: "April", year: 2018]

# explicit
[{:month, "April"}, {:year, 2018}]

キーはアトムでなければなりません

2要素のタプルのリストが、すべてキーワードリストというわけではありません。キーがアトムである必要があります。

Keyword.keyword?([{"month", "April"}])
# => false

キーに文字、数字、_以外の文字を使いたい場合は、引用符で囲む必要があります。ただし、それで文字列になるわけではなく、あくまでアトムのままです。

Keyword.keyword?(["day of week": "Monday"])
# => true

キーは重複させられます

キーワードリストのキーは重複させることができ、キーと値のペアは順序を持ちます。あるキーに対して1つの値を取得しようとすると、最初の値が返され、同じキーにある他の値は黙って無視されます。

list = [month: "April", month: "May"]

Keyword.get_values(list, :month)
# => ["April", "May"]

Keyword.get(list, :month)
# => "April"

キーワードリストはAccessビヘイビアにも対応しています。

list[:month]
# => "April"

オプションとしてのキーワードリスト

こうしたキーワードリストの特徴から、Elixirでは関数にオプションを渡すための標準的な仕組みとしてキーワードリストが使われるようになりました。

ifについて学んだとき、特別な短い構文を見たはずです。

if age >= 16, do: "beer", else: "no beer"

ifが2つの引数を受け取るように見えますが、do:とelse:のペアは実際には1つの引数、つまりキーワードリストです。同じコードは次のようにも書けます。

if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]

キーワードリストを関数のオプションとして使うことは非常によくあるため、Elixirでは、関数に渡す最後の引数がキーワードリストであれば、角括弧を省略できます。

Elixirの構文では、タプルやリスト、マップなども関数呼び出しと同じように扱われるため、これらにも同じ性質が当てはまります。

[1, 2, three: 3]
# => [1, 2, {:three, 3}]

パターンマッチング

簡潔な構文を使ってキーワードリストのパターンマッチングを成功させるには、すべてのキーを正しい順序で指定する必要があります。そのため、キーワードリストを扱うときにパターンマッチングを選ぶことはほとんどありません。代わりにKeywordモジュールやAccessビヘイビアを使いましょう。

[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

キーワードリストとマップの比較

キーワードリスト マップ
キーの型 アトム 任意。1つのマップ内で混在も可能
キーの重複 可 不可
キーの順序 あり なし
アクセス list[:key]、Keyword.get/2 map.key、map[:key]、Map.get/2
アクセス時間 線形 対数
パターンマッチング あまり役に立たない 役に立つ

アクセス時間が速く、キーの型も柔軟で、パターンマッチングも役に立つため、ほとんどの場面でマップが標準的な選択肢になります。

データ量が多くないものの、キーの重複や特定の順序が必要な場合は、キーワードリストを使いましょう。

GitHubで編集 リンクは新しいウィンドウまたはタブで開きます

キーワードリストを学習する

練習はロックされています

キーワードリストを練習するには、あと1個の演習のロックを解除してください