Una lista de palabras clave es una lista de tuplas {key, value}. Hay dos formas de escribir una lista de palabras clave:
# concise
[month: "April", year: 2018]
# explicit
[{:month, "April"}, {:year, 2018}]
No toda lista de tuplas de 2 elementos es una lista de palabras clave. Las claves deben ser átomos:
Keyword.keyword?([{"month", "April"}])
# => false
Si quieres usar caracteres que no sean letras, números ni _ en la clave, necesitas encerrarla entre comillas. Sin embargo, eso no la convierte en un string: sigue siendo un átomo.
Keyword.keyword?(["day of week": "Monday"])
# => true
Las claves en una lista de palabras clave pueden repetirse, y los pares clave-valor están ordenados. Cuando intentas obtener un único valor bajo una clave determinada, obtienes el primer valor, y cualquier otro valor bajo la misma clave se ignora silenciosamente.
list = [month: "April", month: "May"]
Keyword.get_values(list, :month)
# => ["April", "May"]
Keyword.get(list, :month)
# => "April"
Las listas de palabras clave también admiten el Access behaviour.
list[:month]
# => "April"
Las características de las listas de palabras clave las convirtieron en el mecanismo predeterminado para pasar opciones a las funciones en Elixir.
Cuando aprendiste sobre if, viste una sintaxis especial más corta:
if age >= 16, do: "beer", else: "no beer"
Esto puede parecer que if acepta dos argumentos, pero el par do: y else: en realidad es un solo argumento: una lista de palabras clave. El mismo código podría escribirse así:
if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]
El uso de listas de palabras clave como opciones de funciones es tan común que Elixir te permite omitir los corchetes cuando la lista de palabras clave es el último argumento que se pasa a una función.
Como las tuplas, las listas, los mapas y otros se tratan igual que las llamadas a funciones en la sintaxis de Elixir, esta propiedad también está disponible para ellos.
[1, 2, three: 3]
# => [1, 2, {:three, 3}]
Para hacer coincidir correctamente un patrón con una lista de palabras clave usando la sintaxis concisa, tendrías que especificar todas las claves en el orden correcto. Esto hace que la coincidencia de patrones sea una opción poco probable para trabajar con listas de palabras clave. En su lugar, usa el módulo Keyword o el Access behaviour.
[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
| Lista de palabras clave | Mapa | |
|---|---|---|
| Tipo de clave | Átomos | Cualquiera, se pueden mezclar en un mismo mapa |
| Claves duplicadas | Sí | No |
| Claves ordenadas | Sí | No |
| Acceso |
list[:key], Keyword.get/2
|
map.key, map[:key], Map.get/2
|
| Tiempo de acceso | Lineal | Logarítmico |
| Coincidencia de patrones | No muy útil | Útil |
Un tiempo de acceso más rápido, un tipo de clave flexible y una coincidencia de patrones útil hacen que los mapas sean la opción predeterminada en la mayoría de los casos.
Usa listas de palabras clave cuando no tengas muchos datos, pero necesites claves duplicadas o claves en un orden específico.