Binärziffern entsprechen letztlich direkt den Transistoren in deiner CPU oder deinem RAM und ob jeder von ihnen „an" oder „aus" ist.
Low-Level-Manipulation, informell „Bit-Twiddling" genannt, ist in Systemsprachen besonders wichtig.
Hochsprachen wie Julia abstrahieren meist den größten Teil dieser Details.
Allerdings steht in der Basissprache eine ganze Reihe von Bit-Operationen zur Verfügung.
Hinweis: Um im REPL eine für Menschen lesbare binäre Ausgabe zu sehen, müssen fast alle Beispiele unten in eine bitstring()-Funktion eingepackt werden.
Das lenkt optisch ab, deshalb wurden die meisten Vorkommen dieser Funktion herausgenommen.
Bitverschiebungen
Ganzzahltypen, ob vorzeichenbehaftet oder vorzeichenlos, lassen sich als eine Folge von 1en und 0en darstellen.
julia> bitstring(UInt8(5))
"00000101"
Bitverschiebungen verschieben einfach alles um eine bestimmte Anzahl von Positionen nach links oder rechts.
Bei UInt-Typen fallen an einem Ende einige Bits heraus und das andere Ende wird mit Nullen aufgefüllt:
julia> ux::UInt8 = 5
5
julia> bitstring(ux)
"00000101"
julia> ux << 2 # left by 2
"00010100"
julia> ux >> 1 # right by 1
"00000010"
Jede Verschiebung nach links verdoppelt den Wert und jede Verschiebung nach rechts halbiert ihn (vorbehaltlich einer Trunkierung).
In der Dezimaldarstellung ist das deutlicher:
julia> 3 << 2
12
julia> 24 >> 3
3
Solche Bitverschiebungen sind viel schneller als „richtige" Arithmetik, weshalb die Technik beim Low-Level-Programmieren sehr beliebt ist.
Bei vorzeichenbehafteten Ganzzahlen müssen wir etwas vorsichtiger sein.
Verschiebungen nach links sind relativ einfach:
julia> sx = Int8(5)
5
julia> sx # positive integer
"00000101"
julia> sx << 2
"00010100"
julia> -sx # negative integer
"11111011"
julia> -sx << 2
"11101100"
Das Verschieben positiver vorzeichenbehafteter Ganzzahlen nach links ist also dasselbe wie bei vorzeichenlosen Ganzzahlen.
Negative Werte werden in der Zweierkomplement-Form gespeichert, was bedeutet, dass das am weitesten links stehende Bit eine 1 ist.
Für eine Verschiebung nach links ist das kein Problem, aber wie füllen wir beim Verschieben nach rechts die am weitesten links stehenden Bits auf?
julia> sx >> 2 # simple for positive values!
"00000001"
julia> -sx # negative integer
"11111011"
julia> -sx >> 2 # pad with repeated sign bit
"11111110"
julia> -sx >>> 2 # pad with 0
"00111110"
Der Operator >> führt eine arithmetische Verschiebung durch und erhält dabei das Vorzeichenbit.
Der Operator >>> führt eine logische Verschiebung durch und füllt mit Nullen auf, als wäre die Zahl vorzeichenlos.
Bitweise Logik
In einem früheren Konzept haben wir gesehen, dass die Operatoren && (und), || (oder) und ! (nicht) mit booleschen Werten verwendet werden.
Es gibt entsprechende Operatoren & (bitweises Und), | (bitweises Oder) und ~ (eine Tilde, bitweises Nicht), um die Bits zweier Ganzzahlen zu vergleichen.
julia> 0b1011 & 0b0010 # bit is 1 in both numbers
"00000010"
julia> 0b1011 | 0b0010 # bit is 1 in at least one number
"00001011"
julia> ~0b1011 # flip all bits
"11110100"
julia> xor(0b1011, 0b0010) # bit is 1 in exactly one number, not both
"00001001"
Hier ist xor() das exklusive Oder, verwendet als Funktion.
Lernübung
