Números enteros
Notación binaria
Un número entero es una abstracción que representa números sin parte fraccionaria, como 4, -2, 0 o 64532.
Para representar un número entero como una secuencia de bytes, se utiliza la notación binaria.
En esta notación, cada bit de la secuencia representa una potencia de dos distinta, y el valor aumenta a medida que lo hace el índice del bit de derecha a izquierda.
Números sin signo
Si el número solo puede ser no negativo, se denomina número sin signo.
Los números sin signo se representan directamente como la suma de las potencias de dos correspondientes a todos los bits activados de su secuencia.
El rango de números enteros no negativos representables en un registro va desde 0 (ningún bit activado) hasta 2⁶⁴ - 1 (la suma de los 64 bits activados).
Ensanchar un número sin signo a un tamaño mayor se hace rellenando todos los bits superiores con 0, de modo que ningún bit nuevo contribuya al valor.
Esto se denomina extensión de ceros.
La instrucción movzx (z de cero) extiende con ceros un operando origen de 8 o 16 bits a un operando destino de mayor tamaño.
Un operando origen de 32 bits siempre se extiende con ceros a los 64 bits del operando destino con un simple mov.
Números con signo
Si un número entero puede tomar valores positivos o negativos, se denomina número con signo.
Para representar números negativos, x86-64 utiliza la representación en complemento a dos.
En complemento a dos, los números con signo también se representan como la suma de las potencias de dos correspondientes a los bits activados.
Sin embargo, si el bit más alto está activado, se resta en lugar de sumarse a los demás.
Como este bit corresponde a un valor mayor que la suma de todos los demás, en la práctica esto significa que un número con este bit activado siempre es negativo.
Este bit especial se denomina bit de signo.
Ensanchar un número con signo a un tamaño mayor consiste en rellenar cada nuevo bit superior con una copia del bit de signo, de modo que se conserve el valor.
Esto se denomina extensión de signo.
La instrucción movsx (s de signo) extiende el signo de un operando origen de 8 o 16 bits a un operando destino de mayor tamaño.
Una variante de movsx llamada movsxd hace lo mismo desde un operando origen de 32 bits a un operando destino de 64 bits.
La instrucción neg se puede usar para cambiar el signo de un número.
En ensamblador, no hay forma de saber si una secuencia de bytes representa un número con signo o uno sin signo.
Es responsabilidad de quien programa dar significado a esos bytes.
El uso de comentarios puede ser de gran ayuda en esta tarea.
En un concepto anterior se mencionó que un número constante, como 4 o -15, puede usarse como operando origen de muchas instrucciones.
Esos números se denominan inmediatos.
Un inmediato no se guarda en un registro ni en memoria: está codificado dentro de la propia instrucción.
En la mayoría de las instrucciones, el espacio reservado para él es de solo 32 bits, sin importar el tamaño del operando destino.
Cuando el operando destino es de 64 bits, esos 32 bits se extienden con signo para rellenarlo.
La mitad superior del operando se rellena por completo con copias del bit más alto del inmediato, por lo que solo se puede escribir de esta forma un número dentro del rango de un entero con signo de 32 bits:
add rax, -1 ; the immediate is sign-extended, so all 64 bits of rax are affected
add rax, 2147483647 ; the largest immediate an instruction like this accepts
Un número fuera de ese rango no puede usarse como inmediato.
La excepción a esta regla es mov, que puede tomar un inmediato completo de 64 bits cuando el operando destino es un registro.
Si se necesita un inmediato de 64 bits, usa primero mov para cargarlo en un registro y luego usa ese registro:
mov rax, 3435973837 ; this works, mov can take a 64-bit immediate
mov rdx, 18446744073709551615 ; the largest immediate mov accepts
sub rdx, rax
Ten en cuenta que un inmediato negativo y el número sin signo con la misma representación de bits son equivalentes y se ensamblan exactamente al mismo valor:
mov rax, -1 ; rax = 18446744073709551615
mov rax, 18446744073709551615 ; rax = -1
Suma
La suma de dos números se puede calcular con la instrucción add.
También existe la instrucción inc, de un solo operando, que suma 1 al valor de su operando:
inc rax ; rax = rax + 1
La suma de dos números enteros funciona igual tanto para números sin signo como con signo.
Resta
La resta de dos números enteros se realiza con la instrucción sub.
También existe la instrucción dec, de un solo operando, que resta 1 al valor de su operando:
dec rax ; rax = rax - 1
La resta de dos números enteros también funciona igual tanto para números sin signo como con signo.
Multiplicación
Hay dos instrucciones distintas para multiplicar dos números en x86-64.
Por norma general, la multiplicación sin signo usa la instrucción mul, mientras que la multiplicación con signo usa imul.
La instrucción mul adopta la siguiente forma de un solo operando, donde src es el operando origen:
mul src
La instrucción imul puede adoptar la forma de uno, dos o tres operandos:
imul src
imul dest, src
imul dest, src1, src2
Multiplicación de un solo operando
En la forma de un solo operando se usan implícitamente dos registros para realizar la multiplicación: rax y rdx.
Si la multiplicación involucra dos números de 64 bits, los 64 bits inferiores del resultado estarán en rax y los 64 bits superiores estarán en rdx.
Esto se suele denominar rdx:rax, para indicar que ambos registros se usan en conjunto:
mul rcx ; rax = lower 64 bits of rax * rcx
; rdx = upper 64 bits of rax * rcx
Lo mismo ocurre con otros tamaños de operando.
Así, por ejemplo, si se multiplican dos números de 32 bits, se usarán eax y edx.
La excepción es la multiplicación entre dos bytes.
En este caso, en lugar de dl:al, se usará ax.
La parte inferior de ax (al) recibirá los 8 bits inferiores del producto, mientras que la parte superior (ah) recibirá los 8 bits superiores.
Los registros que se usan implícitamente en una multiplicación, como rax y rdx, siempre se sobrescriben.
Los valores de esos registros deben guardarse antes de la operación si se van a necesitar después.
Multiplicación de dos operandos
La forma de dos operandos de imul tiene un operando destino explícito y sigue la sintaxis habitual.
No se usa rdx.
En su lugar, el resultado se trunca para que quepa en el operando destino.
imul r8, r9 ; r8 = lower 64 bits of r8 * r9
Multiplicación de tres operandos
La forma de tres operandos de imul tiene dos operandos origen, el segundo de los cuales es siempre un inmediato (un número constante).
Se multiplican ambos operandos origen y el resultado se trunca y se coloca en el operando destino:
imul r8, r9, 100 ; r8 = lower 64 bits of r9 * 100
Ten en cuenta que el operando destino no se usa en la multiplicación.
Solo recibe el resultado.
Gestión del desbordamiento
Tanto la multiplicación de dos operandos como la de tres operandos truncan el resultado para que quepa en el tamaño del operando destino.
La multiplicación de un solo operando conserva el rango completo, pero normalmente se reparte entre dos registros, rdx y rax.
Por eso, a veces es útil ensanchar los operandos antes de la multiplicación para hacer sitio al producto completo en un solo registro.
Un operando sin signo se extiende con ceros, mientras que uno con signo se extiende con el signo:
movzx eax, di ; di and si hold unsigned 16-bit numbers
movzx ecx, si
mul ecx ; the 32-bit product fits in eax, and edx is cleared
División
Al igual que ocurre con la multiplicación, también hay dos instrucciones para dividir dos números.
La división sin signo usa la instrucción div, mientras que la división con signo usa idiv.
Ambas instrucciones funcionan con un solo operando:
div src
idiv src
La división de 16, 32 y 64 bits usa dx:ax, edx:eax y rdx:rax como dividendo, respectivamente.
En estos casos, ambos registros actúan en conjunto para crear un valor de 2N bits, donde N es el tamaño de la operación (16, 32 o 64 bits).
Este valor se divide entonces entre el operando origen.
El cociente se escribe en ax, eax o rax y el residuo se escribe en dx, edx o rdx, según el tamaño de la operación.
La división entre bytes es especial: en lugar de usar dl:al, se usa ax.
Los 8 bits inferiores de ax (al) recibirán el cociente de la operación y los 8 bits superiores (ah) recibirán el residuo.
Ten en cuenta que todos los bits del dividendo deben estar debidamente establecidos antes de la división.
Cualquier bit activado en rdx (o en ah para la división de 8 bits) contribuye al valor que se divide.
En la división sin signo, cuando el valor que se va a dividir cabe en la mitad inferior, la mitad superior debe ponerse a cero.
Sirve cualquier instrucción que ponga esos bits a cero.
Por ejemplo, mov edx, 0 pone a cero los bits superiores en la división de 32 bits.
En la división con signo, en cambio, el valor debe extenderse con el signo.
Hay instrucciones que automatizan este proceso: cbw, cwd, cdq y cqo.
La primera establece los bits de ah según el signo de al.
Las demás realizan la extensión de signo de ax a dx, de eax a edx y de rax a rdx, respectivamente.
Los registros que se usan implícitamente en una división, como rax y rdx, siempre se sobrescriben.
Los valores de esos registros deben guardarse antes de la división si se van a necesitar después.
Ejercicio de aprendizaje
