在庫管理

整数

2進表記

整数とは、4、-2、0、64532のような数を表す抽象的な概念です。

整数をバイトの並びとして表すには、2進表記を使います。 この表記では、並びの中の各ビットがそれぞれ異なる2の累乗を表し、ビットのインデックスが右から左へ増えるにつれて、その値は大きくなります。

符号なし数値

その数値が負にならない場合、それを符号なしの数値と呼びます。

符号なしの数値は、その並びの中で1になっているすべてのビットに対応する2の累乗の和として、そのまま表されます。

レジスタで表せる負でない整数の範囲は、0（どのビットも1になっていない状態）から2⁶⁴ - 1（64個のビットがすべて1になっている状態の和）までです。

符号なしの数値をより大きなサイズに広げるには、上位のビットをすべて0で埋めます。こうすると、新しいビットが値に寄与することはありません。 これをゼロ拡張と呼びます。

movzx命令（zはゼロの意味）は、8ビットまたは16ビットのソースオペランドを、より大きな宛先オペランドへゼロ拡張します。 32ビットのソースオペランドは、単純なmovによって、常に宛先オペランドの64ビットすべてへゼロ拡張されます。

符号あり数値

整数が正の値と負の値の両方を取りうる場合、それを符号ありの数値と呼びます。

負の数を表すために、x86-64では2の補数表現を使います。

2の補数では、符号ありの数値も、1になっているビットに対応する2の累乗の和として表されます。 ただし、最上位のビットが1になっている場合は、そのビットは他のビットに加算されるのではなく、減算されます。

このビットは他のすべてのビットの和よりも大きな値に対応するため、実際にはこのビットが1の数値は常に負になります。 この特別なビットを符号ビットと呼びます。

符号ありの数値をより大きなサイズに広げるには、新たに増えた上位ビットをすべて符号ビットのコピーで埋めます。こうすると値が保たれます。 これを符号拡張と呼びます。

movsx命令（sは符号の意味）は、8ビットまたは16ビットのソースオペランドを、より大きな宛先オペランドへ符号拡張します。 movsxの派生であるmovsxdは、32ビットのソースオペランドから64ビットの宛先オペランドへ、同じことを行います。

neg命令を使うと、数値の符号を変えられます。

即値

前の概念で、4や-15のような定数を、多くの命令のソースオペランドとして使えることに触れました。 こうした数値を即値と呼びます。

即値はレジスタやメモリに保持されるのではなく、命令そのものの中にエンコードされます。 ほとんどの命令では、宛先オペランドがどれほど大きくても、即値のために確保される領域はわずか32ビット幅です。

宛先オペランドが64ビット幅の場合、その32ビットは、それを埋めるために_符号拡張_されます。 オペランドの上半分は、即値の最上位ビットのコピーで完全に埋められます。そのため、この方法で書けるのは、_32ビット符号あり整数_の範囲の数値だけです：

add rax, -1          ; the immediate is sign-extended, so all 64 bits of rax are affected
add rax, 2147483647  ; the largest immediate an instruction like this accepts

その範囲外の数値は、即値として使えません。 この規則の例外はmovで、宛先オペランドがレジスタの場合は64ビットの即値をそのまま受け取れます。 64ビットの即値が必要な場合は、まずmovでそれをレジスタに読み込み、そのレジスタを使ってください：

mov rax, 3435973837           ; this works, mov can take a 64-bit immediate
mov rdx, 18446744073709551615 ; the largest immediate mov accepts
sub rdx, rax

負の即値と、同じビット表現を持つ符号なしの数値は等価であり、まったく同じ値にアセンブルされることに注意してください：

mov rax, -1                   ; rax = 18446744073709551615
mov rax, 18446744073709551615 ; rax = -1

加算

2つの数値の加算は、add命令で計算できます。

1オペランド命令のincもあり、これはオペランドの値に1を加えます：

inc rax ; rax = rax + 1

2つの整数の和は、符号なしの数値でも符号ありの数値でも、同じように計算されます。

減算

2つの整数の減算は、sub命令で行います。

1オペランド命令のdecもあり、これはオペランドの値から1を引きます：

dec rax ; rax = rax - 1

2つの整数の差も、符号なしの数値でも符号ありの数値でも、同じように計算されます。

乗算

x86-64で2つの数値の乗算を行うには、2つの異なる命令があります。 原則として、符号なしの乗算にはmul命令を、符号ありの乗算にはimulを使います。

mul命令は次の1オペランド形式をとります。ここでsrcはソースオペランドです：

mul src

imul命令は、1オペランド、2オペランド、3オペランドの形式をとれます：

imul src
imul dest, src
imul dest, src1, src2

1オペランドの乗算

1オペランド形式の乗算では、2つのレジスタが暗黙的に使われます。raxとrdxです。 2つの64ビット数の乗算であれば、結果の下位64ビットがraxに、上位64ビットがrdxに入ります。

これは通常rdx:raxと呼ばれ、2つのレジスタが連携して使われることを示します：

mul rcx ; rax = lower 64 bits of rax * rcx
        ; rdx = upper 64 bits of rax * rcx

他のオペランドサイズでも同じことが起こります。 たとえば、2つの32ビット数を掛ける場合は、eaxとedxが使われます。

例外は、2つのバイト同士の乗算です。

この場合、dl:alではなくaxが使われます。 axの下位部分（al）が積の下位8ビットを、上位部分（ah）が上位8ビットを受け取ります。

2オペランドの乗算

imulの2オペランド形式には、明示的な宛先オペランドがあり、通常の構文に従います。 rdxは使われません。 代わりに、結果は宛先オペランドに収まるように切り捨てられます。

imul r8, r9 ; r8 = lower 64 bits of r8 * r9

3オペランドの乗算

imulの3オペランド形式には2つのソースオペランドがあり、その2つ目は常に即値（定数）です。 2つのソースオペランドが掛け合わされ、結果は切り捨てられて宛先オペランドに格納されます：

imul r8, r9, 100 ; r8 = lower 64 bits of r9 * 100

宛先オペランドは乗算には使われないことに注意してください。 単に結果を受け取るだけです。

オーバーフローの扱い

2オペランド形式と3オペランド形式の乗算はどちらも、結果を宛先オペランドのサイズに収まるように切り捨てます。 1オペランド形式の乗算は範囲全体を保ちますが、通常はrdxとraxの2つのレジスタに分けて格納されます。

そのため、積全体を1つのレジスタに収めるために、乗算の前にオペランドを広げておくと便利なことがあります。 符号なしのオペランドはゼロ拡張し、符号ありのオペランドは符号拡張します：

movzx eax, di ; di and si hold unsigned 16-bit numbers
movzx ecx, si
mul ecx       ; the 32-bit product fits in eax, and edx is cleared

除算

乗算の場合と同じく、2つの数値の除算を行う命令も2つあります。 符号なしの除算にはdiv命令を、符号ありの除算にはidivを使います。

どちらの命令も、1つのオペランドだけで動作します：

div src
idiv src

16ビット、32ビット、64ビットの除算では、それぞれdx:ax、edx:eax、rdx:raxを被除数として使います。 この場合、2つのレジスタが連携して2Nビットの値を作ります。ここでNは演算のサイズ（16ビット、32ビット、64ビット）です。 この値がソースオペランドで割られます。 演算のサイズに応じて、商はax、eax、raxに、余りはdx、edx、rdxに書き込まれます。

バイト同士の除算は特別で、dl:alではなくaxを使います。 axの下位8ビット（al）が演算の商を、上位8ビット（ah）が余りを受け取ります。

除算の前に、被除数のすべてのビットを適切に設定しておく必要があることに注意してください。 rdx（8ビット除算ではah）に1になっているビットがあれば、それは割られる値に寄与します。

符号なしの除算では、割られる値が下半分に収まる場合、上半分をクリアしておく必要があります。 それらのビットをクリアする命令なら、どれでもかまいません。 たとえば、mov edx, 0は32ビット除算で上位ビットをクリアします。

符号ありの除算では、代わりにその値を符号拡張します。 この処理を自動で行う命令があります。cbw、cwd、cdq、cqoです。 最初のcbwは、alの符号に応じてahのビットを設定します。 残りの命令は、それぞれaxからdxへ、eaxからedxへ、raxからrdxへ符号拡張を行います。