مدیریت موجودی

اعداد صحیح

نمایش دودویی

عدد صحیح انتزاعی است که نماینده‌ی اعداد بدون جزء اعشاری است، مانند 4، -2، 0 یا 64532.

برای نمایش یک عدد صحیح به‌صورت دنباله‌ای از بایت، از نمایش دودویی استفاده می‌شود. در این نمایش، هر بیت در دنباله نماینده‌ی یک توان مشخص از دو است و مقدار آن با افزایش اندیس بیت از راست به چپ بیشتر می‌شود.

اعداد بدون علامت

اگر عدد فقط بتواند نامنفی باشد، به آن عدد بدون علامت می‌گویند.

اعداد بدون علامت مستقیماً به‌صورت مجموع توان‌های دو متناظر با همه‌ی بیت‌های روشن در دنباله‌شان نمایش داده می‌شوند.

بازه‌ی اعداد صحیح نامنفی قابل نمایش در یک ثبات از 0 (هیچ بیتی روشن نیست) تا 2⁶⁴ - 1 (مجموع همه‌ی ۶۴ بیت روشن) ادامه دارد.

گسترده کردن یک عدد بدون علامت به اندازه‌ی بزرگ‌تر با پر کردن همه‌ی بیت‌های بالایی با 0 انجام می‌شود، طوری که هیچ بیت تازه‌ای در مقدار سهیم نشود. به این کار گسترش صفر می‌گویند.

دستور movzx (حرف z به معنای صفر) عملوند مبدأ ۸ بیتی یا ۱۶ بیتی را به عملوند مقصد بزرگ‌تری گسترش صفر می‌دهد. عملوند مبدأ ۳۲ بیتی همیشه با یک mov ساده به همه‌ی ۶۴ بیت عملوند مقصد گسترش صفر داده می‌شود.

اعداد علامت‌دار

اگر عدد صحیح بتواند مقدارهای مثبت یا منفی بگیرد، به آن عدد علامت‌دار می‌گویند.

برای نمایش اعداد منفی، x86-64 از نمایش مکمل دو استفاده می‌کند.

در مکمل دو، اعداد علامت‌دار نیز به‌صورت مجموع توان‌های دو متناظر با بیت‌های روشن نمایش داده می‌شوند. اما اگر بالاترین بیت روشن باشد، به‌جای اضافه شدن به بقیه، از آن‌ها کم می‌شود.

چون این بیت متناظر با مقداری بزرگ‌تر از مجموع بقیه است، در عمل یعنی عددی که این بیت در آن روشن باشد همیشه منفی است. به این بیت ویژه بیت علامت می‌گویند.

گسترده کردن یک عدد علامت‌دار به اندازه‌ی بزرگ‌تر یعنی پر کردن هر بیت بالایی تازه با نسخه‌ای از بیت علامت، تا مقدار حفظ شود. به این کار گسترش علامت می‌گویند.

دستور movsx (حرف s به معنای علامت) عملوند مبدأ ۸ بیتی یا ۱۶ بیتی را به عملوند مقصد بزرگ‌تری گسترش علامت می‌دهد. گونه‌ای از movsx به نام movsxd همین کار را از یک عملوند مبدأ ۳۲ بیتی به یک عملوند مقصد ۶۴ بیتی انجام می‌دهد.

از دستور neg می‌توان برای تغییر علامت یک عدد استفاده کرد.

مقدارهای آنی

در مفهوم قبلی گفته شد که یک عدد ثابت، مانند 4 یا -15، می‌تواند به‌عنوان عملوند مبدأ بسیاری از دستورها استفاده شود. به این عددها مقدار آنی می‌گویند.

مقدار آنی در ثبات یا در حافظه نگه داشته نمی‌شود: خودش درون دستور کدگذاری می‌شود. در بیشتر دستورها، فضای رزروشده برای آن تنها ۳۲ بیت است، هرقدر هم که عملوند مقصد بزرگ باشد.

وقتی عملوند مقصد ۶۴ بیتی است، آن ۳۲ بیت برای پر کردن آن گسترش علامت داده می‌شوند. نیمه‌ی بالایی عملوند کاملاً با نسخه‌هایی از بالاترین بیت مقدار آنی پر می‌شود، پس فقط عددی در بازه‌ی یک عدد صحیح علامت‌دار ۳۲ بیتی می‌تواند این‌گونه نوشته شود:

add rax, -1          ; the immediate is sign-extended, so all 64 bits of rax are affected
add rax, 2147483647  ; the largest immediate an instruction like this accepts

عددی بیرون از آن بازه نمی‌تواند به‌عنوان مقدار آنی استفاده شود. استثنای این قاعده mov است که وقتی عملوند مقصد یک ثبات باشد، می‌تواند یک مقدار آنی کامل ۶۴ بیتی بگیرد. اگر به یک مقدار آنی ۶۴ بیتی نیاز باشد، اول با mov آن را در یک ثبات بارگذاری کنید، سپس از آن ثبات استفاده کنید:

mov rax, 3435973837           ; this works, mov can take a 64-bit immediate
mov rdx, 18446744073709551615 ; the largest immediate mov accepts
sub rdx, rax

توجه کنید که یک مقدار آنی منفی و عدد بدون علامتی با همان نمایش بیتی هم‌ارزند و به دقیقاً یک مقدار اسمبل می‌شوند:

mov rax, -1                   ; rax = 18446744073709551615
mov rax, 18446744073709551615 ; rax = -1

جمع

جمع دو عدد را می‌توان با دستور add محاسبه کرد.

دستور تک‌عملوندی inc هم هست که 1 را به مقدار عملوندش اضافه می‌کند:

inc rax ; rax = rax + 1

جمع دو عدد صحیح برای اعداد بدون علامت و علامت‌دار یکسان عمل می‌کند.

تفریق

تفریق دو عدد صحیح با دستور sub انجام می‌شود.

دستور تک‌عملوندی dec هم هست که 1 را از مقدار عملوندش کم می‌کند:

dec rax ; rax = rax - 1

تفریق دو عدد صحیح نیز برای اعداد بدون علامت و علامت‌دار یکسان عمل می‌کند.

ضرب

در x86-64 دو دستور متفاوت برای ضرب دو عدد وجود دارد. به‌طور کلی، ضرب بدون علامت از دستور mul و ضرب علامت‌دار از imul استفاده می‌کند.

دستور mul شکل تک‌عملوندی زیر را دارد که در آن src عملوند مبدأ است:

mul src

دستور imul می‌تواند شکل تک‌عملوندی، دو عملوندی یا سه‌عملوندی داشته باشد:

imul src
imul dest, src
imul dest, src1, src2

ضرب تک‌عملوندی

در شکل تک‌عملوندی، دو ثبات به‌طور ضمنی برای انجام ضرب استفاده می‌شوند: rax و rdx. اگر ضرب شامل دو عدد ۶۴ بیتی باشد، ۶۴ بیت پایینی نتیجه در rax و ۶۴ بیت بالایی در rdx قرار می‌گیرد.

معمولاً به این rdx:rax می‌گویند تا نشان دهد هر دو ثبات با هم به کار می‌روند:

mul rcx ; rax = lower 64 bits of rax * rcx
        ; rdx = upper 64 bits of rax * rcx

برای اندازه‌های دیگر عملوند نیز همین اتفاق می‌افتد. برای نمونه، اگر دو عدد ۳۲ بیتی ضرب شوند، از eax و edx استفاده می‌شود.

استثنا، ضرب بین دو بایت است.

در این حالت، به‌جای dl:al از ax استفاده می‌شود. بخش پایینی ax یعنی al ۸ بیت پایینی حاصل‌ضرب را می‌گیرد و بخش بالایی یعنی ah ۸ بیت بالایی را.

ضرب دو عملوندی

شکل دو عملوندی imul یک عملوند مقصد صریح دارد و از نحوه‌ی نگارش معمول پیروی می‌کند. از rdx استفاده نمی‌شود. در عوض، نتیجه بریده می‌شود تا در عملوند مقصد جا بگیرد.

imul r8, r9 ; r8 = lower 64 bits of r8 * r9

ضرب سه‌عملوندی

شکل سه‌عملوندی imul دو عملوند مبدأ دارد که دومی همیشه یک مقدار آنی (یک عدد ثابت) است. هر دو عملوند مبدأ در هم ضرب می‌شوند و نتیجه بریده و در عملوند مقصد قرار می‌گیرد:

imul r8, r9, 100 ; r8 = lower 64 bits of r9 * 100

توجه کنید که عملوند مقصد در ضرب استفاده نمی‌شود. فقط نتیجه را دریافت می‌کند.

مدیریت سرریز

ضرب دو عملوندی و سه‌عملوندی هر دو نتیجه را بر می‌دارند تا در اندازه‌ی عملوند مقصد جا بگیرد. ضرب تک‌عملوندی تمام بازه را حفظ می‌کند، اما معمولاً بین دو ثبات rdx و rax تقسیم می‌شود.

پس گاهی مفید است عملوندها را پیش از ضرب گسترده کنیم تا تمام حاصل‌ضرب در یک ثبات واحد جا بگیرد. عملوند بدون علامت گسترش صفر و عملوند علامت‌دار گسترش علامت داده می‌شود:

movzx eax, di ; di and si hold unsigned 16-bit numbers
movzx ecx, si
mul ecx       ; the 32-bit product fits in eax, and edx is cleared

تقسیم

همان‌ند ضرب، دو دستور نیز برای تقسیم دو عدد وجود دارد. تقسیم بدون علامت از دستور div و تقسیم علامت‌دار از idiv استفاده می‌کند.

هر دو دستور فقط با یک عملوند کار می‌کنند:

div src
idiv src

تقسیم ۱۶ بیتی، ۳۲ بیتی و ۶۴ بیتی به‌ترتیب از dx:ax، edx:eax و rdx:rax به‌عنوان مقسوم استفاده می‌کنند. در این حالت‌ها، هر دو ثبات با هم یک مقدار ۲N بیتی می‌سازند که N اندازه‌ی عملیات (۱۶ بیتی، ۳۲ بیتی یا ۶۴ بیتی) است. این مقدار سپس بر عملوند مبدأ تقسیم می‌شود. خارج‌قسمت در ax، eax یا rax و باقی‌مانده در dx، edx یا rdx نوشته می‌شود، بسته به اندازه‌ی عملیات.

تقسیم بین بایت‌ها ویژه است: به‌جای dl:al از ax استفاده می‌شود. ۸ بیت پایینی ax یعنی al خارج‌قسمت عملیات را می‌گیرد و ۸ بیت بالایی یعنی ah باقی‌مانده را.

توجه کنید که همه‌ی بیت‌های مقسوم باید پیش از تقسیم به‌درستی تنظیم شده باشند. هر بیت روشنی در rdx (یا در ah برای تقسیم ۸ بیتی) در مقدار در حال تقسیم سهیم است.

در تقسیم بدون علامت، وقتی مقدار در حال تقسیم در نیمه‌ی پایینی جا می‌گیرد، نیمه‌ی بالایی باید صفر شود. هر دستوری که آن بیت‌ها را صفر کند کافی است. برای نمونه، mov edx, 0 بیت‌های بالایی را در تقسیم ۳۲ بیتی صفر می‌کند.

در تقسیم علامت‌دار، در عوض باید مقدار گسترش علامت داده شود. دستورهایی هستند که این فرایند را خودکار می‌کنند: cbw، cwd، cdq و cqo. اولی بیت‌های ah را بر اساس علامت al تنظیم می‌کند. بقیه به‌ترتیب گسترش علامت را از ax به dx، از eax به edx و از rax به rdx انجام می‌دهند.